• Общие вопросы
• Пример Telnet интерфейса

Управление программой через Telnet интерфейс

Общие вопросы

• Утилита Telnet есть на любом компьютере с операционной системой Windows, UNIX, AIX и т.п., поэтому ее не требуется писать или устанавливать
• Telnet является штатным средством удаленного администрирования.
• Telnet подразумевает текстовый обмен, поэтому его очень легко поддерживать в своей программе
• Возможностей текстового терминала как правило достаточно для управления программой, ее настройки и администрирования

Рассмотрим немного теории. Утилиту Telnet легче всего запустить через Start->Run (Пуск -> Выполнить). После запуска необходимо произвести соединение с удаленным хостом, для чего выполняется используется меню "Connect->Remote System". При этом выводится меню соединения, в котором необходимо указать три параметра: хост, порт и тип терминала. В качестве хоста указывается имя удаленного компьютера (или его IP адрес), порт можно задать двумя путями - выбором/вводом символического имени (например, telnet), или вводом номера порта. Мы будем пользоваться вторым путем, т.е. будем использовать нестандартные номера портов. Тип терминала оставим vt100.
Утилита Telnet поддерживает параметры командой строки:

telnet [remote_host] [port]

telnet zaitsevov или telnet zaitsevov 5000

Пример Telnet интерфейса

Итак, приступим к разработке приложения. Создадим пустой проект и поместим на форму компонент ServerSocket1 типа TServerSocket. Зададим ему порт, например 5000. Напоминаю, что:

• номер порта должен быть нестандартным, чтобы не пересекаться с другими программами. При этом желательно считывать его из INI файла, что даст возможность настройки при необходимости.
• Свойство Active должно быть false и устанавливаться в true при запуске программы. Иначе приложение свалится при попытке запуска второй копии или при отсутствии сети. Установку Active := true следует делать в блоке try ... except

begin
 try
  ServerSocket1.Active := true;
 except
  ShowMessage('Ошибки при активации ServerSocket');
 end;
end;

procedure TMain.ServerSocket1ClientConnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
 Socket.SendText('Connected. Программа Telnet1 Example на проводе.'+#$0D+#$0A);
 Socket.SendText('Enter password : ');
 Connected := false;
 Memo1.Lines.Add('Произошло соединение с пользователем');
end;

• Выводить информацию при соединении желательно на английском языке. Это позволяет избежать ситуации, когда на компьтере администратора не окажется поддержки русского языка в кодировке, используемой программой, и Telnet выведет ему абракадабру вместо текста. У меня это наблюдается постоянно на английской NT 4 - приходится каждый раз лезть в настройки Telnet и задавать русский CharSet. Аналогичные проблемы могут быть при работе утилитой telnet из операционных систем *nix
• При соединении следует обязательно запросить пароль. Иначе любой "хацкер" сможет подключиться к программе и управлять ей (из практики - преценденты были).
• Следует особое внимание уделить обработке ошибок - опечатки при вводе команд неизбежны, следовательно их необходимо корректно обрабатывать. Желательно при обнаружении ошибки выдавать контекстную справку по ошибочной команде
• Необходимо предусмотреть справочную систему по командам, поддерживаемым программой - эта справка послужит в качестве экспресс-шпаргалки

// Поддержка связи по TCP/IP для удаленного конфигурирования - действия при отключении
procedure TMain.ServerSocket1ClientDisconnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
   Connected := false;
   Memo1.Lines.Add('Соединение разорвано');
end;

• Создавать (при необходимости) эхо для всех принимаемых символов. Очевидно, что при вводе паролей эхо создавать не нужно. При созании эха необходимо учитывать, что символ с кодом FF (буква "я") должен повторяться дважды, иначе он будет погложен Telnet - ом как служебный и не отобразится
• Накапливать вводимые символы, ожидая прихода признака конца команы. Как правило, признаком конца команды считают перевод код строки (следует заметить, что тут разработчик сам себе стандарт, но отклоняться от общепринятых правил не рекомендуется. Для накопления принимаемой информации стоит завести буферную переменную, в моем случае она будет называться TelnetS.
• При получении символа с кодом 08h ("BackSpace") необходимо не помещать ее в буфер, а стереть из буфера последний символ. Но в виде эха его отправить необходимо, т.к. это приведет к стиранию символа на экране Telnet (при подавлении эха он останется на экране, но сотрется в буфере программы, что приведет к путанице).
• При обнаружении символа перевода строки (код $0D) следует считать содержимое буфера командой и интерпретировать. Как - это отдельный разговор

// Поддержка связи по TCP/IP для удаленного конфигурирования - действия при получении данных
procedure TForm1.ServerSocket1ClientRead(Sender: TObject;
  Socket: TCustomWinSocket);
var
 s, st : string;
begin
 s := Socket.ReceiveText;
 // Это код перевода строки ? Если да, то выполняем команду и передаем ее ответ клиенту
 if ord(s[1]) = $0D then begin
  st := ExecuteCMD(TelnetS);
  if st <> '' then
   st := #$0D + #$0A + st;
  st := st + #$0D + #$0A + '>';
  TelnetSendText(Socket, st);
  TelnetS := '';
  exit;
 end;
 // Это код клавиши BackSpace. Если да, то передадим его клиенту
 // и удалим последний символ из буфера
 if ord(s[1]) = $08 then begin
  Delete(TelnetS, length(TelnetS), 1);
  TelnetSendText(Socket, s);
  exit;
 end;
 // Добавим очередной символ к буферу
 TelnetS := TelnetS + s;
 // Передадим его клиенту для организации эха
 if connected then
  TelnetSendText(Socket, s);
end;

// Передача ответа/эха клиенту
function TForm1.TelnetSendText(Socket: TCustomWinSocket; AText: string): boolean;
var
 i  : integer;
 St : string;
begin
 Result := false;
 if Not(connected) then
  exit;
 St := '';
 for i := 1 to length(AText) do
  if AText[i] <> #$FF then st := st + AText[i]
   else st := st + #$FF + #$FF;
 Socket.SendText(st);
end;

// Интерретатор команд
function TForm1.ExecuteCMD(ACmd: string): string;
var
 UCmd, Params  : string;
begin
 Result := '';
 Memo1.Lines.Add('Выполняется : '+ACmd);
 if Not(connected) then begin
  if UpperCase(ACmd) = '123' then begin
   Connected := true;
   Result := 'Пользователь идентифицирован !';
  end;
  exit;
 end;
 // Выделение команды
 UCmd := ACmd;
 Params := '';
 if pos(' ', UCmd) > 0 then begin
  Params := Copy(UCmd, pos(' ', UCmd)+1, Length(UCmd));
  UCmd := Copy(UCmd, 1, pos(' ', UCmd)-1);
 end;
 UCmd := Trim(UpperCase(UCMD));
 Memo1.Lines.Add('Выделена команда : '+UCmd);
 // ? или HLP или HELP - вывод справки
 if (UCmd = '?') or (UCmd = 'HLP') or (UCmd = 'HELP') then begin
  Result :=
   'Краткая справка по командам Telnet интерфейса'+CRLF+
   '  ?, HLP, HELP - вызов справки'+CRLF+
   ' EXIT - завершение работы по Telnen интерфейсу'+CRLF+
   ' HALT - немедленный останов программы'+CRLF+
   ' VER - версия программы'+CRLF+
   ' MESS <собщение> - вывод сообщения для пользователя'+CRLF+
   ' INP <собщение> - вывод сообщения для пользователя и возврат его ответа';
  exit;
 end;
 if (UCmd = 'EXIT') then begin
  ServerSocket1.Socket.Connections[0].Close;
  exit;
 end;
 if (UCmd = 'VER') then begin
  Result := 'Версия 1.00 от 27.01.2001 (C) Зайцев Олег';
  exit;
 end;
 if (UCmd = 'HALT') then begin
  halt;
 end;
 if (UCmd = 'MESS') then begin
  ShowMessage(Params);
  exit;
 end;
 if (UCmd = 'INP') then begin
  Result := InputBox(Params,'Введите ответ','');
  exit;
 end;
  Result := 'Неизвестная команда '+ACmd;
end;

• ?, HLP, HELP для вывода справочной информации (практика показала, что при поддерке 20-30 команд больше половины забываются за месяц)
• EXIT - завершение обмена

  
procedure TForm1.ServerSocket1ClientError(Sender: TObject;
  Socket: TCustomWinSocket; ErrorEvent: TErrorEvent;
  var ErrorCode: Integer);
begin
 // Обработка события "разрыв соединения"
 if ErrorCode = 10054 then begin
  Socket.Close;
  ErrorCode := 0;
 end;
end;

© Зайцев Олег, "Программирование на Delphi - обмен опытом" 1999-2004. При использовании любых материалов данного сайта необходимо указывать источник информации. Дата обновления: 22.11.2004. Сайт размещен на хостинге AGAVA - Хостинг от AGAVA.ru